Fermi Golden Rule:

Simplest Possible Problem.

1. Unperturbed Problem

Description

The unperturbed problem describes a particle of mass m which is free apart from a negative δ-function potential at the origin: V(x)=-W δ(x).

I shall units units such that m, ℏ and W are all 1:

Length Unit: (ℏ^2)/ m W

Momentum (p) Unit: m W /ℏ

Time Unit:  (ℏ^3)/ m (W^2)

Frequency (ω) Unit: m(W^2)/ (ℏ^3)

Energy Unit: m  (W^2)/ (ℏ^2)

Force Unit: (m^2)(W^3)/(ℏ^4)

Bound State

This problem has a single bound state:

e0:=-1/2     (* Eigenvalue*)

u0[x_]:=E^(-Abs[x])    (*Eigenfuntion*)

td0[t_]:=E^(-I e0 t) (*Time Dependence*)

Integrate[u0[x]^2,{x,-Infinity,Infinity}] (*Check normalisation*)

Continuum States

There is a continuum of positive energy states - in fact an even and odd parity state for every energy. We shall only require the odd-parity states:

e[p_]:=p^2/2

uminus[p_,x_]:=Sin[p x]/Sqrt[Pi]

uplus[p_,x_]:=Cos[p Abs[x]+ArcCot[p]]/Sqrt[Pi]

td[p_,t_]:=E^(-I e[p] t)

tdstar[p_,t_]:=E^(I e[p] t)

Plots

Plot[{uminus[1,x],uplus[1,x],u0[x]},{x,-10,10},PlotStyle->{Blue,Green,Red},AxesLabel->Automatic,LabelStyle->18,Epilog->{Text[Style["(Subscript[u, 0])(x)",18,Red],{-5,0.8},{-1,-1}],Text[Style["\!\(\*Cell[TextData[Cell[BoxData[
FormBox[
RowBox[{
SubscriptBox["u", "-"], "(", 
RowBox[{"1", ",", "x"}], ")"}], TraditionalForm]]]]]\)",18,Blue],{1,0.8},{-1,-1}],Text[Style["\!\(\*Cell[TextData[Cell[BoxData[
FormBox[
RowBox[{
SubscriptBox["u", 
RowBox[{"-", "+"}]], "(", 
RowBox[{"1", ",", "x"}], ")"}], TraditionalForm]]]]]\)",18,Green],{6,0.8},{-1,-1}]}]

Perturbation

The perturbing Hamiltonian is - F x (e^(-iωt)):

ω:=1/2+pres^2/2

pres:=1

tdpert[t_]:=E^(-I ω t)

2. Perturbation Theory

First-Order Wavefunction Correction

The first-order-corrected wavefunction is

ψ(x,t)=(Subscript[u, 0])(x,t)(e^(-(Subscript[iE, 0])t))+F∫a(p,t)(SubMinus[u])(p,x)(e^(-(Subscript[iE, p])t))dp

(the F makes the correction explicitly first-order) where the coefficients a(p,t) are given by

a(p,t)=i<p,-|x|0>∫(e^((Subscript[iE, p])t))(e^(-iωt))(e^(-(Subscript[iE, 0])t))dt.

Matrix Element

This is the matrix element of x between the bound state and the odd-parity continuum:

brapxket0[p_]=Integrate[uminus[p,x] x u0[x],{x,-Infinity,Infinity},Assumptions->Element[p,Reals]]

Plot[brapxket0[p],{p,0,10},AxesLabel->Automatic,Epilog->Text[Style["<p,-|x|0>",Blue,18],{5,0.6},{-1,-1}],LabelStyle->18]

Time-dependent Factor

The integral in the time-dependent factor contains only exponentials and is straightforward:

tdcoeff[p_,t_]=Integrate[tdstar[p,t1] tdpert[t1] td0[t1],{t1,0,t}]

tdpres[t_]=Limit[tdcoeff[p,t],p->pres]

Coefficients

The a(p,t) coefficients are the product of the matrix element and the time-dependent factor:

coeff[p_,t_]=I brapxket0[p] tdcoeff[p,t]

coeffpres[t_]=I brapxket0[pres] tdpres[t]

padd={{30,30},{20,6}}

tmax=50

ratio= brapxket0[1/Sqrt[3]]/brapxket0[pres]

Manipulate[GraphicsColumn[{Plot[If[plot1,brapxket0[p],Abs[tdcoeff[p,t]]],{p,0,5},AspectRatio->1/GoldenRatio,LabelStyle->18,PlotRange->{{0,5},{0,If[plot1,0.75,If[norm,t,tmax]]}},ImagePadding->padd,Epilog->Text[Style[If[plot1,"Matrix Element","|Time-dependent Factor|"],18,Blue],Scaled[{0.9,0.7}],{1,-1}]],Plot[Abs[coeff[p,t]],{p,0,5},AspectRatio->1/GoldenRatio,AxesLabel->{p,None},LabelStyle->18,PlotRange->{{0,5},{0.,If[norm,ratio*Abs[coeffpres[t]],Abs[coeffpres[tmax]]]}},ImagePadding->padd,Epilog->Text[Style["\!\(\*Cell[TextData[Cell[BoxData[
FormBox[
RowBox[{"|", 
RowBox[{"a", "(", 
RowBox[{"p", ",", "t"}], ")"}], "|"}], TraditionalForm]]]]]\)",18,Blue],Scaled[{0.7,0.7}],{-1,-1}]]},ImageSize->Large],{t,0.1,tmax},{norm,{True,False}},{plot1,{True,False}}]

Total Transition Probability and Fermi Golden Rule Approximation

The total Transition Probability is found by integrating |a(p)((|)^2) over p.

Manipulate[Plot[Abs[coeff[p,t]]^2,{p,0,5},AspectRatio->1/GoldenRatio,AxesLabel->{p,None},LabelStyle->18,Filling->Bottom,PlotRange->{{0,5},{0.,If[norm,ratio^2*Abs[coeffpres[t]]^2,Abs[coeffpres[tmax]]^2]}},ImagePadding->padd,Epilog->Text[Style["\!\(\*Cell[TextData[Cell[BoxData[
FormBox[
RowBox[{"|", 
RowBox[{"a", "(", "p", ")"}], 
SuperscriptBox["|", "2"]}], TraditionalForm]]]]]\)",18,Blue],Scaled[{0.7,0.7}],{-1,-1}],ImageSize->Large],{t,0.1,tmax},{norm,{True,False}}]

Plot[{NIntegrate[Abs[coeff[p,t]]^2,{p,0,Infinity}],2 Pi t Abs[brapxket0[pres]]^2/pres},{t,0,60},PlotStyle->{Blue,Red},AxesLabel->{t,None},LabelStyle->18,Epilog->{Text[Style["Excitation P(t):",18,Black],Scaled[{0.6,0.4}],{-1,-1}],Text[Style["Full First Order",18,Blue],Scaled[{0.6,0.3}],{-1,-1}],Text[Style["Fermi Golden Rule Approx",18,Red],Scaled[{0.6,0.2}],{-1,-1}]},ImageSize->Large]

Plot[NIntegrate[Abs[coeff[p,t]]^2,{p,0,Infinity}]-2 Pi t brapxket0[pres]^2/pres,{t,0,60},AxesLabel->{t,None},LabelStyle->18,ImageSize->Large,Epilog->Text[Style["First Order - FGR Approx",18,Blue],Scaled[{0.3,0.8}],{-1,-1}]]